MousePaint.bas

10 BORDER 1: PAPER 7: INK 0: BRIGHT 0: FLASH 0: CLS: LET C=0: LET B=0: LET D=0: LET M=0
20 FOR I=0 TO 7: PAPER I: BRIGHT 1: PRINT AT 20,I;" ";: NEXT I
30 PAPER 7: INK 0: PRINT AT 20,9;"BRIGHT";
40 BRIGHT 0: FOR I=0 TO 7: PAPER I: PRINT AT 21,I;" ";: NEXT I
50 PAPER 7: PRINT AT 21,9;"NEW ERASE FILL";
60 PLOT 0,16: DRAW 255,0
70 IF _MB=0 THEN LET D=0: GO TO 70
80 LET X=_MX: LET Y=_MY: LET OX=_OMX: LET OY=_OMY
90 IF X<0 THEN GO TO 70
100 IF Y<17 THEN GO TO 200
110 INK C: BRIGHT B
120 IF M=2 AND D=0 THEN FILL X,Y: LET D=1: GO TO 70
125 IF M=2 THEN GO TO 70
130 IF D=1 AND OX>=0 AND OY>=17 THEN GO TO 150
140 IF M=1 THEN PLOT ERASE;X,Y: LET D=1: GO TO 70
145 PLOT X,Y: LET D=1: GO TO 70
150 IF M=1 THEN PLOT ERASE;OX,OY: DRAW ERASE;X-OX,Y-OY: GO TO 70
155 PLOT OX,OY: DRAW X-OX,Y-OY
160 GO TO 70
200 LET D=0: IF Y=16 THEN GO TO 70
210 IF X<64 THEN LET C=INT (X/8): LET B=INT (Y/8): LET M=0: GO TO 70
220 IF Y>=8 THEN GO TO 70
230 IF X>=72 AND X<96 THEN GO TO 10
240 IF X>=104 AND X<144 THEN LET M=1: GO TO 70
250 IF X>=152 AND X<184 THEN LET M=2
260 GO TO 70