vimade+vim-tmux-focus-events creating unnecessary activity while switching windows

[chunleng]

vimade+vim-tmux-focus-events works perfectly while switching between tmux panes. However, it also gets trigger when I try to switch between window and trigger highlight on the windows tab due to activity (vimade changing the color of the vim)

This might be a factor to consider for usability as it practically made the activity notification of tmux useless.

[TaDaa]

This is a great idea, if I'm understanding correctly you would want to separate the actual focus events from tmux pane switching. Unfortunately, it seems that the window focus and pane focus events are entangled together when set -g focus-events on is set. There could be ways around it, if I have time at some point I might take a look.

[TaDaa]

so this may be possible... Maybe just need vim-tmux-focus-events to issue a separate doautocmd specifically to track tmux events instead of only overlapping the editor FocusGained/FocusLost.

I'll give it a go later in the week and see if the author will accept the PR if it works.

[ericboehs]

I'm interested in this as well. I asked Claude Code to investigate. Here's what it came up with:

The issue is that vimade registers global FocusGained and FocusLost autocmd events (lines 623-624), and these fire whenever vim gets/loses focus - which happens both for tmux pane switching AND tmux window switching.

To implement a fix that distinguishes between pane and window focus, the author could:

1. Add a configuration option to control focus event granularity, like:

let g:vimade = {'enablefocusfading': 1, 'tmux_pane_only': 1}

2. Check tmux context in the focus functions by detecting if the focus change was within the same tmux session/window:

function! vimade#FocusLost()
  " Only fade if we're switching tmux windows, not panes
  if exists('$TMUX') && g:vimade.tmux_pane_only
    let current_pane = system('tmux display-message -p "#{pane_id}"')
    " Store pane info and compare on FocusGained
    return
  endif
  " existing logic...

3. Use tmux hooks instead of vim focus events:

" Register tmux-specific hooks that can distinguish pane vs window focus
au User VimadeTmuxPaneChanged call vimade#FadeActive()

[ericboehs]

Just reading over the comment I posted from yesterday; I'm not sure that tmux command would work if it ran too quickly (it would have the wrong pane_id). And you'd just want to fade on tmux pane switch (rather than window).

I ended up removing the window_activity_flag from my status line (opting for just window_bell_flag). That was a sufficient fix for my use case (at least so far).

[TaDaa]

Thanks for sharing @ericboehs !

I'm partially open to this suggestion actually. This solution looks like it could be made to work for users who run both tmux and neovim remotely. Blending local tmux and remote neovim won't work.

I think I'd prefer to keep the detection logic separate from Vimade, so probably a shared dotfile config that detects the pane change (chaining it off FocusLost/FocusGained should work) and then just run VimadeFadeActive / VimadeUnfadeActive commands accordingly. We also need to bypass the pausing logic -- it probably makes sense to update [Un]fadeActive commands to do the unpause.

[TaDaa]

Ok I think this should work for both Neovim and Vim (assuming tmux command is available to the editor). It could make sense to move tmux handling into a separate plugin:

Note: just make sure to update vimade and that vimade.enablefocusfading is disabled in your config (default is disabled)

let g:tmux_command='tmux'
let g:current_pane=-1

function! UpdateFocus(has_focus)
  let l:pane_changed = 0
  let l:next_pane = system(g:tmux_command . ' display-message -p "#{pane_index}"')
  if v:shell_error != 0
    return
  endif
  let l:next_pane = str2nr(l:next_pane)
  if l:next_pane != g:current_pane
    let g:current_pane = l:next_pane
    if a:has_focus
      doautocmd User TmuxPaneFocusGained
    else
      doautocmd User TmuxPaneFocusLost
    endif
  endif
endfunction

augroup DetectFocusChanged
  au!
  au FocusGained * call UpdateFocus(1)
  au FocusLost * call UpdateFocus(0)
augroup END

call UpdateFocus(1)

augroup VimadeTmuxHooks
  au!
  au User TmuxPaneFocusGained VimadeUnfadeActive
  au User TmuxPaneFocusLost VimadeFadeActive
augroup END