PythonPortable/FirstTimeInit.bat at main · GrosSlava/PythonPortable · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
rem Copyright (c) 2023 GrosSlava
@echo off


set EnvName=PyEnv


:begin
if exist %EnvName% (
	echo Already installed!
	goto end
)

rem Create environment main dir
mkdir %EnvName%
cd %EnvName%

rem Create tmp dir
mkdir tmp

rem Copy needed content
xcopy /S /E "..\Install\Scripts\" "."

rem Reset Windows main variables
set APPDATA=%~dp0%EnvName%\tmp
set TEMP=%~dp0%EnvName%\tmp
set USERPROFILE=%~dp0%EnvName%\tmp

rem Install Git
echo Installing Git...
tar -xf "..\Install\git2.40.zip"
set GIT=%~dp0%EnvName%\git\cmd\git.exe

rem Install Python
echo Installing Python...
tar -xf "..\Install\python3.10.zip"
set PYTHON=%~dp0%EnvName%\python\python.exe

rem Clear all other system paths
set PATH=%~dp0%EnvName%\git\cmd\;%~dp0%EnvName%\python\

rem Create environment
echo Creating environment...
python -m venv venv
set VENV_DIR=%~dp0%EnvName%\venv
call "venv\Scripts\activate.bat"

rem Install needed tools
echo "------------------Tools-----------------"
python -m pip install --upgrade pip
echo "----------------------------------------"

rem Install requirements
pip install -r ..\Install\Requirements.txt

rem Show versions
echo "------------Current veriosns------------"
python -V
pip -V
pip list
echo "----------------------------------------"

:end
pause